home *** CD-ROM | disk | FTP | other *** search
/ QRZ! Ham Radio 8 / QRZ Ham Radio Callsign Database - Volume 8.iso / pc / files / dsp / a56_10sh.z / a56_10sh / examples / effects / reverb.a56 < prev   
Text File  |  1996-06-25  |  8KB  |  310 lines
  1. ;***************************************************************
  2. ; 
  3. ; A stereo reverb for the DSP56001 signal processor.
  4. ; Developed by Quinn Jensen (jensenq@npd.novell.com) using
  5. ; Dr. Vercoe and company's csound code as a reference for the 
  6. ; configuration and gain values.
  7. ; 
  8. ; This program fragment implements a stereo reberb effect
  9. ; on a DSP56001 processor.  The "depth" and wet/dry mix are
  10. ; adjustable.  The following filter configuration is employed:
  11. ;
  12. ;
  13. ;  Left in ------+------- "dry" gain -----------> sum -----> Left out
  14. ;                |                                 ^
  15. ;                v                                 |
  16. ;               sum --> reverb --> "wet" gain -----+
  17. ;                ^                                 |
  18. ;                |                                 v -
  19. ;  Right in -----+------- "dry" gain -----------> sum -----> Right out
  20. ;
  21. ;
  22. ; Note that the reverb path output is negated before summing with the
  23. ; right input signal.  This throws in 180 degrees of phase shift
  24. ; making for interesting results even with mono inputs 
  25. ; (i.e. Left in == Right in).
  26. ; 
  27. ; The reverb element looks like this:
  28. ;
  29. ;
  30. ; Input ----+-----> comb1 ------+
  31. ;           |                   |
  32. ;           +-----> comb2 ---\  v
  33. ;           |                  sum -----> allpass1 --> allpass2 ---> output
  34. ;           +-----> comb3 ---/  ^
  35. ;           |                   |
  36. ;           +-----> comb4 ------+
  37. ;
  38. ; Each comb stage looks like this:
  39. ;
  40. ;                        +---- gain <-----+
  41. ;                        |                |
  42. ;                        v                |
  43. ; Input ---> gain ----> sum ---> delay ---+--> out
  44. ;
  45. ;
  46. ; The allpass stages look like:
  47. ;
  48. ;                         +--------- gain <---------+
  49. ;                         |                         |
  50. ;                         v                         |
  51. ; Input ---> gain --+--> sum ---> delay ---> sum ---+----> out
  52. ;                   |                         ^
  53. ;                   |                         |
  54. ;                   +--------> gain ----------+
  55. ;
  56. ; or,
  57. ;
  58. ;                             +-------> gain ----+
  59. ;                             |                  |
  60. ;                             |                  v
  61. ; Input ---> gain ----> sum --+--> delay --+--> sum -----> out
  62. ;                        ^                 |
  63. ;                        |                 |
  64. ;                        +----- gain <-----+
  65. ;
  66. ;
  67. ; I've seen both configurations in the literature, so I plotted the
  68. ; Z-transform and they are equivalent in the steady state.  They are indeed
  69. ; all-pass in the steady state but are supposed to have a subtle, discernable
  70. ; effect in "transient" audio signals.
  71. ;
  72. ; I think it could really use a couple more comb stages to fill in some of the 
  73. ; graininess.  The best possible "diffusion" is desired.  By the way, 
  74. ; I'd enjoy seeing any optimizations to the code.
  75. ;
  76. ; Quinn Jensen (jensenq@npd.novell.com or jensenq@qcj.icon.com)
  77. ;
  78.  
  79. include 'tdsg.basic.a56'    ;hardware specific initialization code
  80.  
  81. ;***************************************************************
  82. ;
  83. ;    Data and constants
  84. ;
  85. ;***************************************************************
  86.  
  87. dot                ;remember where we were in P-space
  88.     org    x:$10        ;put runtime variables in on-chip X-space
  89.  
  90. ; A spreadsheet was used to calculate the following numbers
  91. ;
  92. ; The gain of each feedback stage is given by
  93. ;
  94. ;    feedback gain = exp(delay * ln(.001)/duration)
  95. ;
  96. ; where "delay" is the delay of the comb or allpass stage in seconds,
  97. ; and "duration" is the time in seconds for the reverberated sound
  98. ; to decay to 1/1000 of its original amplitude.
  99. ;
  100.  
  101. ;  Reverb filter lengths and coefficients  
  102. ;  Sun Aug  4 16:36:16 1991    
  103. ;  
  104. ;      Sample rate               32.5520830 kHz      
  105. ;      Reverb duration            4.0000000 s        
  106. ;  
  107. ;  stage    delay(ms)    length        gain    actual
  108. ;  -----------------------------------------------------       
  109. ;  Comb1   29.7000000       967   0.9500031     29.71
  110. ;  Comb2   37.1000000      1208   0.9379399     37.11
  111. ;  Comb3   41.1000000      1338   0.9314831     41.10
  112. ;  Comb4   43.7000000      1423   0.9273101     43.71
  113. ;  All-1    5.0000000       163   0.9914025      5.01
  114. ;  All-2    1.7000000        55   0.9970685      1.69
  115.  
  116. in_atten equ                      0.3409091
  117. comb_atten equ                    0.0416667
  118. dry_init equ                      0.4000000    initial "dry" gain
  119. reverb_init equ                   0.9900000    initial "wet" gain
  120.  
  121. ; comb 1 data and parameters
  122.  
  123. c1d equ                   $4000
  124. c1r  dc                     c1d
  125. c1m equ                     966
  126. c1c equ                           0.9500031
  127.  
  128. ; comb 2 data and parameters
  129.  
  130. c2d equ          c1d+      2048
  131. c2r  dc                     c2d
  132. c2m equ                    1207
  133. c2c equ                           0.9379399
  134.  
  135. ; comb 3 data and parameters
  136.  
  137. c3d equ          c2d+      2048
  138. c3r  dc                     c3d
  139. c3m equ                    1337
  140. c3c equ                           0.9314831
  141.  
  142. ; comb 4 data and parameters
  143.  
  144. c4d equ          c3d+      2048
  145. c4r  dc                     c4d
  146. c4m equ                    1422
  147. c4c equ                           0.9273101
  148.  
  149. ; allpass 1 data and parameters
  150.  
  151. a1d equ          c4d+      2048
  152. a1r  dc                     a1d
  153. a1m equ                     162
  154. a1c equ                           0.9914025
  155.  
  156. ; allpass 2 data and parameters
  157.  
  158. a2d equ          a1d+      2048
  159. a2r  dc                     a2d
  160. a2m equ                      54
  161. a2c equ                           0.9970685
  162.  
  163.     org    y:$0
  164.  
  165. reverb_on equ    reverb_init
  166. reverb_off equ    0
  167.  
  168. reverb_gain
  169.     dc    reverb_on
  170. dry_gain
  171.     dc    dry_init
  172.  
  173.     org    p:dot        ;go back to P-space
  174.  
  175. ;*****************************************************
  176. ;
  177. ; reverb initialization code
  178. ;
  179. ;*****************************************************
  180.  
  181. reverb_init
  182.     rts
  183.  
  184. ;*****************************************************
  185. ;
  186. ; run-time controls
  187. ;
  188. ;*****************************************************
  189.  
  190. eff1_on        ;enable reverb
  191.     move            #reverb_on,y0
  192.     move            y0,y:<reverb_gain
  193.     rts
  194.  
  195. eff1_off    ;bypass reverb
  196.     move            #reverb_off,y0
  197.     move            y0,y:<reverb_gain
  198.     rts
  199.  
  200. ;*****************************************************
  201. ;
  202. ; interrupt time calculations
  203. ;
  204. ;*****************************************************
  205.  
  206. ;
  207. ; fs = 32.552083 kHz
  208. ;
  209.  
  210. reverb_comp
  211.     jsr    <saveregs
  212. ;
  213. ;    L/R mix
  214. ;
  215.     clr    a    #in_atten,x1        ;clr a, get scale for mix
  216.     move        x:<in_l,x0        ;get left in
  217.     move        x0,x:<in_ls        ;save
  218.     macr    x0,x1,a x:<in_r,x0        ;a = scale * left, get right
  219.     macr    x0,x1,a    x0,x:<in_rs        ;a += scale * right, save right
  220.     clr    b        a,y0        ;y0 goes to the combs, b is sum
  221. ;
  222. ;    comb 1 
  223. ;
  224.     move        x:<c1r,r0
  225.     movec        #c1m,m0
  226.     move            y0,a
  227.     move        x:(r0),x1
  228.     add    x1,b    #c1c,x0
  229.     macr    x0,x1,a
  230.     move        a,x:(r0)+
  231.     move        r0,x:<c1r
  232. ;
  233. ;    comb 2
  234. ;
  235.     move        x:<c2r,r0
  236.     movec        #c2m,m0
  237.     move            y0,a
  238.     move        x:(r0),x1
  239.     add    x1,b    #c2c,x0
  240.     macr    x0,x1,a
  241.     move        a,x:(r0)+
  242.     move        r0,x:<c2r
  243. ;
  244. ;    comb 3
  245. ;
  246.     move        x:<c3r,r0
  247.     movec        #c3m,m0
  248.     move            y0,a
  249.     move        x:(r0),x1
  250.     add    x1,b    #c3c,x0
  251.     macr    x0,x1,a
  252.     move        a,x:(r0)+
  253.     move        r0,x:<c3r
  254. ;
  255. ;    comb 4
  256. ;
  257.     move        x:<c4r,r0
  258.     movec        #c4m,m0
  259.     move            y0,a
  260.     move        x:(r0),x1
  261.     add    x1,b    #c4c,x0
  262.     macr    x0,x1,a
  263.     move        a,x:(r0)+
  264.     move        r0,x:<c4r
  265. ;
  266. ;    scale
  267. ;
  268.     move        #comb_atten,x0    b,y0
  269.     mpyr    x0,y0,b
  270.  
  271. ;
  272. ;    allpass 1
  273. ;
  274.     move        x:<a1r,r0
  275.     movec        #a1m,m0
  276.     move        #a1c,x0
  277.     move        x:(r0),x1
  278.     macr    x0,x1,b    x1,a
  279.     move            b,y0
  280.     macr    -x0,y0,a b,x:(r0)+
  281.     move        r0,x:<a1r
  282. ;
  283. ;    allpass 2
  284. ;
  285.     move        x:<a2r,r0
  286.     movec        #a2m,m0
  287.     move        #a2c,x0
  288.     move        x:(r0),x1
  289.     macr    x0,x1,a    x1,b
  290.     move            a,y0
  291.     macr    -x0,y0,b a,x:(r0)+
  292.     move        r0,x:<a2r
  293. ;
  294. ;    output mix
  295. ;
  296.     move        b,x0
  297.     move            y:<reverb_gain,y0
  298.     mpyr    x0,y0,b        y:<dry_gain,y0
  299.     move        x:<in_ls,x0
  300.     move        b,a
  301.     macr    x0,y0,a    x:<in_rs,x0
  302.     macr    x0,y0,b    a,x:<out_l
  303.     move        b,x:<out_r
  304.  
  305.     jsr    <restregs
  306.     rts
  307.  
  308.     end
  309.  
  310.